Version 3

src/MyPrayerJournal/.gitignore

@@ -0,0 +1,5 @@
+## LiteDB database file
+*.db
+
+## Development settings
+appsettings.Development.json

src/MyPrayerJournal/Data.fs

@@ -0,0 +1,209 @@
+module MyPrayerJournal.Data
+
+open LiteDB
+open NodaTime
+open System
+open System.Threading.Tasks
+
+// fsharplint:disable MemberNames
+
+/// LiteDB extensions
+[<AutoOpen>]
+module Extensions =
+  
+  /// Extensions on the LiteDatabase class
+  type LiteDatabase with
+    /// The Request collection
+    member this.requests
+      with get () = this.GetCollection<Request> "request"
+    /// Async version of the checkpoint command (flushes log)
+    member this.saveChanges () =
+      this.Checkpoint ()
+      Task.CompletedTask
+
+
+/// Map domain to LiteDB
+//  It does mapping, but since we're so DU-heavy, this gives us control over the JSON representation
+[<RequireQualifiedAccess>]
+module Mapping =
+  
+  /// Map a history entry to BSON
+  let historyToBson (hist : History) : BsonValue =
+    let doc = BsonDocument ()
+    doc["asOf"]   <- hist.asOf.ToUnixTimeMilliseconds ()
+    doc["status"] <- RequestAction.toString hist.status
+    doc["text"]   <- match hist.text with Some t -> t | None -> ""
+    upcast doc
+
+  /// Map a BSON document to a history entry
+  let historyFromBson (doc : BsonValue) =
+    { asOf   = Instant.FromUnixTimeMilliseconds doc["asOf"].AsInt64
+      status = RequestAction.ofString doc["status"].AsString
+      text   = match doc["text"].AsString with "" -> None | txt -> Some txt
+      }
+
+  /// Map a note entry to BSON
+  let noteToBson (note : Note) : BsonValue =
+    let doc = BsonDocument ()
+    doc["asOf"]  <- note.asOf.ToUnixTimeMilliseconds ()
+    doc["notes"] <- note.notes
+    upcast doc
+
+  /// Map a BSON document to a note entry
+  let noteFromBson (doc : BsonValue) =
+    { asOf  = Instant.FromUnixTimeMilliseconds doc["asOf"].AsInt64
+      notes = doc["notes"].AsString
+      }
+
+  /// Map a request to its BSON representation
+  let requestToBson req : BsonValue =
+    let doc = BsonDocument ()
+    doc["_id"]          <- RequestId.toString req.id
+    doc["enteredOn"]    <- req.enteredOn.ToUnixTimeMilliseconds ()
+    doc["userId"]       <- UserId.toString req.userId
+    doc["snoozedUntil"] <- req.snoozedUntil.ToUnixTimeMilliseconds ()
+    doc["showAfter"]    <- req.showAfter.ToUnixTimeMilliseconds ()
+    doc["recurType"]    <- Recurrence.toString req.recurType
+    doc["recurCount"]   <- BsonValue req.recurCount
+    doc["history"]      <- BsonArray (req.history |> List.map historyToBson |> Seq.ofList)
+    doc["notes"]        <- BsonArray (req.notes   |> List.map noteToBson    |> Seq.ofList)
+    upcast doc
+  
+  /// Map a BSON document to a request
+  let requestFromBson (doc : BsonValue) =
+    { id           = RequestId.ofString doc["_id"].AsString
+      enteredOn    = Instant.FromUnixTimeMilliseconds doc["enteredOn"].AsInt64
+      userId       = UserId doc["userId"].AsString
+      snoozedUntil = Instant.FromUnixTimeMilliseconds doc["snoozedUntil"].AsInt64
+      showAfter    = Instant.FromUnixTimeMilliseconds doc["showAfter"].AsInt64
+      recurType    = Recurrence.ofString doc["recurType"].AsString
+      recurCount   = int16 doc["recurCount"].AsInt32
+      history      = doc["history"].AsArray |> Seq.map historyFromBson |> List.ofSeq
+      notes        = doc["notes"].AsArray   |> Seq.map noteFromBson    |> List.ofSeq
+      }
+  
+  /// Set up the mapping
+  let register () = 
+    BsonMapper.Global.RegisterType<Request>(
+      Func<Request, BsonValue> requestToBson, Func<BsonValue, Request> requestFromBson)
+
+/// Code to be run at startup
+module Startup =
+  
+  /// Ensure the database is set up
+  let ensureDb (db : LiteDatabase) =
+    db.requests.EnsureIndex (fun it -> it.userId) |> ignore
+    Mapping.register ()
+
+
+/// Async wrappers for LiteDB, and request -> journal mappings
+[<AutoOpen>]
+module private Helpers =
+
+  open System.Linq
+
+  /// Convert a sequence to a list asynchronously (used for LiteDB IO)
+  let toListAsync<'T> (q : 'T seq) =
+    (q.ToList >> Task.FromResult) ()
+
+  /// Convert a sequence to a list asynchronously (used for LiteDB IO)
+  let firstAsync<'T> (q : 'T seq) =
+    q.FirstOrDefault () |> Task.FromResult
+
+  /// Async wrapper around a request update
+  let doUpdate (db : LiteDatabase) (req : Request) =
+    db.requests.Update req |> ignore
+    Task.CompletedTask
+
+
+/// Retrieve a request, including its history and notes, by its ID and user ID
+let tryFullRequestById reqId userId (db : LiteDatabase) = backgroundTask {
+  let! req = db.requests.Find (Query.EQ ("_id", RequestId.toString reqId)) |> firstAsync
+  return match box req with null -> None | _ when req.userId = userId -> Some req | _ -> None
+  }
+
+/// Add a history entry
+let addHistory reqId userId hist db = backgroundTask {
+  match! tryFullRequestById reqId userId db with
+  | Some req -> do! doUpdate db { req with history = hist :: req.history }
+  | None     -> invalidOp $"{RequestId.toString reqId} not found"
+  }
+
+/// Add a note
+let addNote reqId userId note db = backgroundTask {
+  match! tryFullRequestById reqId userId db with
+  | Some req -> do! doUpdate db { req with notes = note :: req.notes }
+  | None     -> invalidOp $"{RequestId.toString reqId} not found"
+  }
+
+/// Add a request
+let addRequest (req : Request) (db : LiteDatabase) =
+  db.requests.Insert req |> ignore
+
+// FIXME: make a common function here
+
+/// Retrieve all answered requests for the given user
+let answeredRequests userId (db : LiteDatabase) = backgroundTask {
+  let! reqs = db.requests.Find (Query.EQ ("userId", UserId.toString userId)) |> toListAsync
+  return
+    reqs
+    |> Seq.map JournalRequest.ofRequestFull
+    |> Seq.filter (fun it -> it.lastStatus = Answered)
+    |> Seq.sortByDescending (fun it -> it.asOf)
+    |> List.ofSeq
+  }
+
+/// Retrieve the user's current journal
+let journalByUserId userId (db : LiteDatabase) = backgroundTask {
+  let! jrnl = db.requests.Find (Query.EQ ("userId", UserId.toString userId)) |> toListAsync
+  return
+    jrnl
+    |> Seq.map JournalRequest.ofRequestLite
+    |> Seq.filter (fun it -> it.lastStatus <> Answered)
+    |> Seq.sortBy (fun it -> it.asOf)
+    |> List.ofSeq
+  }
+
+/// Does the user have any snoozed requests?
+let hasSnoozed userId now (db : LiteDatabase) = backgroundTask {
+  let! jrnl = journalByUserId userId db
+  return jrnl |> List.exists (fun r -> r.snoozedUntil > now)
+  }
+
+/// Retrieve a request by its ID and user ID (without notes and history)
+let tryRequestById reqId userId db = backgroundTask {
+  let! req = tryFullRequestById reqId userId db
+  return req |> Option.map (fun r -> { r with history = []; notes = [] })
+  }
+
+/// Retrieve notes for a request by its ID and user ID
+let notesById reqId userId (db : LiteDatabase) = backgroundTask {
+  match! tryFullRequestById reqId userId db with | Some req -> return req.notes | None -> return []
+  }
+    
+/// Retrieve a journal request by its ID and user ID
+let tryJournalById reqId userId (db : LiteDatabase) = backgroundTask {
+  let! req = tryFullRequestById reqId userId db
+  return req |> Option.map JournalRequest.ofRequestLite
+  }
+    
+/// Update the recurrence for a request
+let updateRecurrence reqId userId recurType recurCount db = backgroundTask {
+  match! tryFullRequestById reqId userId db with
+  | Some req -> do! doUpdate db { req with recurType = recurType; recurCount = recurCount }
+  | None     -> invalidOp $"{RequestId.toString reqId} not found"
+  }
+
+/// Update a snoozed request
+let updateSnoozed reqId userId until db = backgroundTask {
+  match! tryFullRequestById reqId userId db with
+  | Some req -> do! doUpdate db { req with snoozedUntil = until; showAfter = until }
+  | None     -> invalidOp $"{RequestId.toString reqId} not found"
+  }
+
+/// Update the "show after" timestamp for a request
+let updateShowAfter reqId userId showAfter db = backgroundTask {
+  match! tryFullRequestById reqId userId db with
+  | Some req -> do! doUpdate db { req with showAfter = showAfter }
+  | None     -> invalidOp $"{RequestId.toString reqId} not found"
+  }

src/MyPrayerJournal/Dates.fs

@@ -0,0 +1,78 @@
+/// Date formatting helpers
+//  Many thanks to date-fns (https://date-fns.org) for this logic
+module MyPrayerJournal.Dates
+
+open NodaTime
+
+type internal FormatDistanceToken =
+  | LessThanXMinutes
+  | XMinutes
+  | AboutXHours
+  | XHours
+  | XDays
+  | AboutXWeeks
+  | XWeeks
+  | AboutXMonths
+  | XMonths
+  | AboutXYears
+  | XYears
+  | OverXYears
+  | AlmostXYears
+
+let internal locales =
+  let format = PrintfFormat<int -> string, unit, string, string>
+  Map.ofList [
+    "en-US", Map.ofList [
+      LessThanXMinutes, ("less than a minute", format "less than %i minutes")
+      XMinutes,         ("a minute",           format "%i minutes")
+      AboutXHours,      ("about an hour",      format "about %i hours")
+      XHours,           ("an hour",            format "%i hours")
+      XDays,            ("a day",              format "%i days")
+      AboutXWeeks,      ("about a week",       format "about %i weeks")
+      XWeeks,           ("a week",             format "%i weeks")
+      AboutXMonths,     ("about a month",      format "about %i months")
+      XMonths,          ("a month",            format "%i months")
+      AboutXYears,      ("about a year",       format "about %i years")
+      XYears,           ("a year",             format "%i years")
+      OverXYears,       ("over a year",        format "over %i years")
+      AlmostXYears,     ("almost a year",      format "almost %i years")
+    ]
+  ]
+
+let aDay        =  1_440.
+let almost2Days =  2_520.
+let aMonth      = 43_200.
+let twoMonths   = 86_400.
+
+open System
+
+/// Convert from a JavaScript "ticks" value to a date/time
+let fromJs ticks = DateTime.UnixEpoch + TimeSpan.FromTicks (ticks * 10_000L)
+
+let formatDistance (startDate : Instant) (endDate : Instant) =
+  let format (token, number) locale =
+    let labels = locales |> Map.find locale
+    match number with 1 -> fst labels[token] | _ -> sprintf (snd labels[token]) number
+  let round (it : float) = Math.Round it |> int
+
+  let diff        = startDate - endDate
+  let minutes     = Math.Abs diff.TotalMinutes
+  let formatToken =
+    let months = minutes / aMonth |> round
+    let years  = months / 12
+    match true with
+    | _ when minutes < 1.          -> LessThanXMinutes, 1
+    | _ when minutes < 45.         -> XMinutes, round minutes
+    | _ when minutes < 90.         -> AboutXHours, 1
+    | _ when minutes < aDay        -> AboutXHours, round (minutes / 60.)
+    | _ when minutes < almost2Days -> XDays, 1
+    | _ when minutes < aMonth      -> XDays, round (minutes / aDay)
+    | _ when minutes < twoMonths   -> AboutXMonths, round (minutes / aMonth)
+    | _ when months      < 12      -> XMonths, round (minutes / aMonth)
+    | _ when months % 12 < 3       -> AboutXYears, years
+    | _ when months % 12 < 9       -> OverXYears, years
+    | _                            -> AlmostXYears, years + 1
+  
+  format formatToken "en-US"
+  |> match startDate > endDate with true -> sprintf "%s ago" | false -> sprintf "in %s"
+

src/MyPrayerJournal/Domain.fs

@@ -0,0 +1,213 @@
+[<AutoOpen>]
+/// The data model for myPrayerJournal
+module MyPrayerJournal.Domain
+
+// fsharplint:disable RecordFieldNames
+
+open Cuid
+open NodaTime
+
+/// An identifier for a request
+type RequestId =
+  | RequestId of Cuid
+
+/// Functions to manipulate request IDs
+module RequestId =
+  /// The string representation of the request ID
+  let toString = function RequestId x -> Cuid.toString x
+  /// Create a request ID from a string representation
+  let ofString = Cuid >> RequestId
+
+
+/// The identifier of a user (the "sub" part of the JWT)
+type UserId =
+  | UserId of string
+
+/// Functions to manipulate user IDs
+module UserId =
+  /// The string representation of the user ID
+  let toString = function UserId x -> x
+
+
+/// How frequently a request should reappear after it is marked "Prayed"
+type Recurrence =
+  | Immediate
+  | Hours
+  | Days
+  | Weeks
+
+/// Functions to manipulate recurrences
+module Recurrence =
+  /// Create a string representation of a recurrence
+  let toString =
+    function
+    | Immediate -> "Immediate"
+    | Hours     -> "Hours"
+    | Days      -> "Days"
+    | Weeks     -> "Weeks"
+  /// Create a recurrence value from a string
+  let ofString =
+    function
+    | "Immediate" -> Immediate
+    | "Hours"     -> Hours
+    | "Days"      -> Days
+    | "Weeks"     -> Weeks
+    | it          -> invalidOp $"{it} is not a valid recurrence"
+  /// An hour's worth of seconds
+  let private oneHour = 3_600L
+  /// The duration of the recurrence (in milliseconds)
+  let duration x =
+    (match x with
+    | Immediate -> 0L
+    | Hours     -> oneHour
+    | Days      -> oneHour * 24L
+    | Weeks     -> oneHour * 24L * 7L)
+
+
+/// The action taken on a request as part of a history entry
+type RequestAction =
+  | Created
+  | Prayed
+  | Updated
+  | Answered
+
+
+/// History is a record of action taken on a prayer request, including updates to its text
+[<CLIMutable; NoComparison; NoEquality>]
+type History = {
+  /// The time when this history entry was made
+  asOf   : Instant
+  /// The status for this history entry
+  status : RequestAction
+  /// The text of the update, if applicable
+  text   : string option
+  }
+
+/// Note is a note regarding a prayer request that does not result in an update to its text
+[<CLIMutable; NoComparison; NoEquality>]
+type Note = {
+  /// The time when this note was made
+  asOf  : Instant
+  /// The text of the notes
+  notes : string
+  }
+
+/// Request is the identifying record for a prayer request
+[<CLIMutable; NoComparison; NoEquality>]
+type Request = {
+  /// The ID of the request
+  id           : RequestId
+  /// The time this request was initially entered
+  enteredOn    : Instant
+  /// The ID of the user to whom this request belongs ("sub" from the JWT)
+  userId       : UserId
+  /// The time at which this request should reappear in the user's journal by manual user choice
+  snoozedUntil : Instant
+  /// The time at which this request should reappear in the user's journal by recurrence
+  showAfter    : Instant
+  /// The type of recurrence for this request
+  recurType    : Recurrence
+  /// How many of the recurrence intervals should occur between appearances in the journal
+  recurCount   : int16
+  /// The history entries for this request
+  history      : History list
+  /// The notes for this request
+  notes        : Note list
+  }
+with
+  /// An empty request
+  static member empty =
+    { id           = Cuid.generate () |> RequestId
+      enteredOn    = Instant.MinValue
+      userId       = UserId ""
+      snoozedUntil = Instant.MinValue
+      showAfter    = Instant.MinValue
+      recurType    = Immediate
+      recurCount   = 0s
+      history      = []
+      notes        = []
+      }
+
+/// JournalRequest is the form of a prayer request returned for the request journal display. It also contains
+/// properties that may be filled for history and notes.
+[<NoComparison; NoEquality>]
+type JournalRequest = {
+  /// The ID of the request (just the CUID part)
+  requestId    : RequestId
+  /// The ID of the user to whom the request belongs
+  userId       : UserId
+  /// The current text of the request
+  text         : string
+  /// The last time action was taken on the request
+  asOf         : Instant
+  /// The last status for the request
+  lastStatus   : RequestAction
+  /// The time that this request should reappear in the user's journal
+  snoozedUntil : Instant
+  /// The time after which this request should reappear in the user's journal by configured recurrence
+  showAfter    : Instant
+  /// The type of recurrence for this request
+  recurType    : Recurrence
+  /// How many of the recurrence intervals should occur between appearances in the journal
+  recurCount   : int16
+  /// History entries for the request
+  history      : History list
+  /// Note entries for the request
+  notes        : Note list
+  }
+
+/// Functions to manipulate journal requests
+module JournalRequest =
+
+  /// Convert a request to the form used for the journal (precomputed values, no notes or history)
+  let ofRequestLite (req : Request) =
+    let hist = req.history |> List.sortByDescending (fun it -> it.asOf) |> List.tryHead
+    { requestId    = req.id
+      userId       = req.userId
+      text         = req.history
+                      |> List.filter (fun it -> Option.isSome it.text)
+                      |> List.sortByDescending (fun it -> it.asOf)
+                      |> List.tryHead
+                      |> Option.map (fun h -> Option.get h.text)
+                      |> Option.defaultValue ""
+      asOf         = match hist with Some h -> h.asOf   | None -> Instant.MinValue
+      lastStatus   = match hist with Some h -> h.status | None -> Created
+      snoozedUntil = req.snoozedUntil
+      showAfter    = req.showAfter
+      recurType    = req.recurType
+      recurCount   = req.recurCount
+      history      = []
+      notes        = []
+      }
+
+  /// Same as `ofRequestLite`, but with notes and history
+  let ofRequestFull req =
+    { ofRequestLite req with 
+        history = req.history
+        notes   = req.notes
+      }
+
+
+/// Functions to manipulate request actions
+module RequestAction =
+  /// Create a string representation of an action
+  let toString =
+    function
+    | Created  -> "Created"
+    | Prayed   -> "Prayed"
+    | Updated  -> "Updated"
+    | Answered -> "Answered"
+  /// Create a RequestAction from a string
+  let ofString =
+    function
+    | "Created"  -> Created
+    | "Prayed"   -> Prayed
+    | "Updated"  -> Updated
+    | "Answered" -> Answered
+    | it         -> invalidOp $"Bad request action {it}"
+  /// Determine if a history's status is `Created`
+  let isCreated hist = hist.status = Created
+  /// Determine if a history's status is `Prayed`
+  let isPrayed hist = hist.status = Prayed
+  /// Determine if a history's status is `Answered`
+  let isAnswered hist = hist.status = Answered

src/MyPrayerJournal/Handlers.fs

@@ -0,0 +1,603 @@
+/// HTTP handlers for the myPrayerJournal API
+[<RequireQualifiedAccess>]
+module MyPrayerJournal.Handlers
+
+// fsharplint:disable RecordFieldNames
+
+open Giraffe
+open Giraffe.Htmx
+open Microsoft.AspNetCore.Authentication
+open Microsoft.AspNetCore.Http
+open System
+open System.Security.Claims
+open NodaTime
+
+/// Helper function to be able to split out log on
+[<AutoOpen>]
+module private LogOnHelpers =
+
+  /// Log on, optionally specifying a redirected URL once authentication is complete
+  let logOn url : HttpHandler =
+    fun next ctx -> backgroundTask {
+      match url with
+      | Some it ->
+          do! ctx.ChallengeAsync ("Auth0", AuthenticationProperties (RedirectUri = it))
+          return! next ctx
+      | None -> return! challenge "Auth0" next ctx
+      }
+
+/// Handlers for error conditions
+module Error =
+
+  open Microsoft.Extensions.Logging
+  open System.Threading.Tasks
+
+  /// Handle errors
+  let error (ex : Exception) (log : ILogger) =
+    log.LogError (EventId(), ex, "An unhandled exception has occurred while executing the request.")
+    clearResponse
+    >=> setStatusCode 500
+    >=> setHttpHeader "X-Toast" (sprintf "error|||%s: %s" (ex.GetType().Name) ex.Message)
+    >=> text ex.Message
+
+  /// Handle unauthorized actions, redirecting to log on for GETs, otherwise returning a 401 Not Authorized reponse
+  let notAuthorized : HttpHandler =
+    fun next ctx ->
+      (next, ctx)
+      ||> match ctx.Request.Method with
+          | "GET" -> logOn None
+          | _ -> setStatusCode 401 >=> fun _ _ -> Task.FromResult<HttpContext option> None
+
+  /// Handle 404s from the API, sending known URL paths to the Vue app so that they can be handled there
+  let notFound : HttpHandler =
+    setStatusCode 404 >=> text "Not found"
+
+
+/// Handler helpers
+[<AutoOpen>]
+module private Helpers =
+  
+  open LiteDB
+  open Microsoft.Extensions.Logging
+  open Microsoft.Net.Http.Headers
+
+  let debug (ctx : HttpContext) message =
+    let fac = ctx.GetService<ILoggerFactory>()
+    let log = fac.CreateLogger "Debug"
+    log.LogInformation message
+
+  /// Get the LiteDB database
+  let db (ctx : HttpContext) = ctx.GetService<LiteDatabase>()
+
+  /// Get the user's "sub" claim
+  let user (ctx : HttpContext) =
+    ctx.User
+    |> Option.ofObj
+    |> Option.map (fun user -> user.Claims |> Seq.tryFind (fun u -> u.Type = ClaimTypes.NameIdentifier))
+    |> Option.flatten
+    |> Option.map (fun claim -> claim.Value)
+
+  /// Get the current user's ID
+  //  NOTE: this may raise if you don't run the request through the requiresAuthentication handler first
+  let userId ctx =
+    (user >> Option.get) ctx |> UserId
+
+  /// Get the system clock
+  let clock (ctx : HttpContext) =
+    ctx.GetService<IClock> ()
+  
+  /// Get the current instant
+  let now ctx =
+    (clock ctx).GetCurrentInstant ()
+
+  /// Return a 201 CREATED response
+  let created =
+    setStatusCode 201
+
+  /// Return a 201 CREATED response with the location header set for the created resource
+  let createdAt url : HttpHandler =
+    fun next ctx ->
+      (sprintf "%s://%s%s" ctx.Request.Scheme ctx.Request.Host.Value url |> setHttpHeader HeaderNames.Location
+       >=> created) next ctx
+  
+  /// Return a 303 SEE OTHER response (forces a GET on the redirected URL)
+  let seeOther (url : string) =
+    noResponseCaching >=> setStatusCode 303 >=> setHttpHeader "Location" url
+
+  /// Render a component result
+  let renderComponent nodes : HttpHandler =
+    noResponseCaching
+    >=> fun next ctx -> backgroundTask {
+      return! ctx.WriteHtmlStringAsync (ViewEngine.RenderView.AsString.htmlNodes nodes)
+      }
+
+  open Views.Layout
+
+  /// Create a page rendering context
+  let pageContext (ctx : HttpContext) pageTitle content = backgroundTask {
+    let! hasSnoozed = backgroundTask {
+      match user ctx with
+      | Some _ -> return! Data.hasSnoozed (userId ctx) (now ctx) (db ctx)
+      | None   -> return  false
+      }
+    return {
+      isAuthenticated = (user >> Option.isSome) ctx
+      hasSnoozed      = hasSnoozed
+      currentUrl      = ctx.Request.Path.Value
+      pageTitle       = pageTitle
+      content         = content
+      }
+    }
+
+  /// Composable handler to write a view to the output
+  let writeView view : HttpHandler =
+    fun next ctx -> backgroundTask {
+      return! ctx.WriteHtmlViewAsync view
+      }
+
+  /// Hold messages across redirects
+  module Messages =
+
+    /// The messages being held
+    let mutable private messages : Map<string, (string * string)> = Map.empty
+
+    /// Locked update to prevent updates by multiple threads
+    let private upd8 = obj ()
+
+    /// Push a new message into the list
+    let push ctx message url = lock upd8 (fun () ->
+      messages <- messages.Add (ctx |> (user >> Option.get), (message, url)))
+
+    /// Add a success message header to the response
+    let pushSuccess ctx message url =
+      push ctx (sprintf "success|||%s" message) url
+    
+    /// Pop the messages for the given user
+    let pop userId = lock upd8 (fun () ->
+      let msg = messages.TryFind userId
+      msg |> Option.iter (fun _ -> messages <- messages.Remove userId)
+      msg)
+
+  /// Send a partial result if this is not a full page load (does not append no-cache headers)
+  let partialStatic (pageTitle : string) content : HttpHandler =
+    fun next ctx -> backgroundTask {
+      let  isPartial = ctx.Request.IsHtmx && not ctx.Request.IsHtmxRefresh
+      let! pageCtx   = pageContext ctx pageTitle content
+      let  view      = (match isPartial with true -> partial | false -> view) pageCtx
+      return! 
+        (next, ctx)
+        ||> match user ctx with
+            | Some u ->
+                match Messages.pop u with
+                | Some (msg, url) -> setHttpHeader "X-Toast" msg >=> withHxPush url >=> writeView view
+                | None -> writeView view
+            | None -> writeView view
+      }
+   
+  /// Send an explicitly non-cached result, rendering as a partial if this is not a full page load
+  let partial pageTitle content =
+    noResponseCaching >=> partialStatic pageTitle content
+
+  /// Add a success message header to the response
+  let withSuccessMessage : string -> HttpHandler =
+    sprintf "success|||%s" >> setHttpHeader "X-Toast"
+  
+  /// Hide a modal window when the response is sent
+  let hideModal (name : string) : HttpHandler =
+    setHttpHeader "X-Hide-Modal" name
+
+
+/// Strongly-typed models for post requests
+module Models =
+  
+  /// An additional note
+  [<CLIMutable; NoComparison; NoEquality>]
+  type NoteEntry = {
+    /// The notes being added
+    notes : string
+    }
+  
+  /// A prayer request
+  [<CLIMutable; NoComparison; NoEquality>]
+  type Request = {
+    /// The ID of the request
+    requestId     : string
+    /// Where to redirect after saving
+    returnTo      : string
+    /// The text of the request
+    requestText   : string
+    /// The additional status to record
+    status        : string option
+    /// The recurrence type
+    recurType     : string
+    /// The recurrence count
+    recurCount    : int16 option
+    /// The recurrence interval
+    recurInterval : string option
+    }
+  
+  /// The date until which a request should not appear in the journal
+  [<CLIMutable; NoComparison; NoEquality>]
+  type SnoozeUntil = {
+    /// The date (YYYY-MM-DD) at which the request should reappear
+    until : string
+    }
+
+
+open MyPrayerJournal.Data.Extensions
+open NodaTime.Text
+
+/// Handlers for less-than-full-page HTML requests
+module Components =
+
+  // GET /components/journal-items
+  let journalItems : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let  now   = now ctx
+      let! jrnl  = Data.journalByUserId (userId ctx) (db ctx)
+      let  shown = jrnl |> List.filter (fun it -> now > it.snoozedUntil && now > it.showAfter)
+      return! renderComponent [ Views.Journal.journalItems now shown ] next ctx
+      }
+  
+  // GET /components/request-item/[req-id]
+  let requestItem reqId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      match! Data.tryJournalById (RequestId.ofString reqId) (userId ctx) (db ctx) with
+      | Some req -> return! renderComponent [ Views.Request.reqListItem (now ctx) req ] next ctx
+      | None     -> return! Error.notFound next ctx
+      }
+
+  // GET /components/request/[req-id]/add-notes
+  let addNotes requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> renderComponent (Views.Journal.notesEdit (RequestId.ofString requestId))
+
+  // GET /components/request/[req-id]/notes
+  let notes requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let! notes = Data.notesById (RequestId.ofString requestId) (userId ctx) (db ctx)
+      return! renderComponent (Views.Request.notes (now ctx) notes) next ctx
+      }
+  
+  // GET /components/request/[req-id]/snooze
+  let snooze requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> renderComponent [ RequestId.ofString requestId |> Views.Journal.snooze ]
+
+
+/// / URL    
+module Home =
+  
+  // GET /
+  let home : HttpHandler =
+    partialStatic "Welcome!" Views.Layout.home
+  
+
+/// /journal URL
+module Journal =
+  
+  // GET /journal
+  let journal : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let usr =
+        ctx.User.Claims
+        |> Seq.tryFind (fun c -> c.Type = ClaimTypes.GivenName)
+        |> Option.map (fun c -> c.Value)
+        |> Option.defaultValue "Your"
+      let title = usr |> match usr with "Your" -> sprintf "%s" | _ -> sprintf "%s's"
+      return! partial (sprintf "%s Prayer Journal" title) (Views.Journal.journal usr) next ctx
+    }
+
+
+/// /legal URLs
+module Legal =
+  
+  // GET /legal/privacy-policy
+  let privacyPolicy : HttpHandler =
+    partialStatic "Privacy Policy" Views.Legal.privacyPolicy
+  
+  // GET /legal/terms-of-service
+  let termsOfService : HttpHandler =
+    partialStatic "Terms of Service" Views.Legal.termsOfService
+
+
+/// /api/request and /request(s) URLs
+module Request =
+
+  // GET /request/[req-id]/edit  
+  let edit requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let returnTo =
+        match ctx.Request.Headers.Referer.[0] with
+        | it when it.EndsWith "/active"  -> "active"
+        | it when it.EndsWith "/snoozed" -> "snoozed"
+        | _                              -> "journal"
+      match requestId with
+      | "new" ->
+          return! partial "Add Prayer Request"
+                    (Views.Request.edit (JournalRequest.ofRequestLite Request.empty) returnTo true) next ctx
+      | _     ->
+          match! Data.tryJournalById (RequestId.ofString requestId) (userId ctx) (db ctx) with
+          | Some req ->
+              debug ctx "Found - sending view"
+              return! partial "Edit Prayer Request" (Views.Request.edit req returnTo false) next ctx
+          | None     ->
+              debug ctx "Not found - uh oh..."
+              return! Error.notFound next ctx
+      }
+
+  // PATCH /request/[req-id]/prayed
+  let prayed requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let db    = db     ctx
+      let usrId = userId ctx
+      let reqId = RequestId.ofString requestId
+      match! Data.tryRequestById reqId usrId db with
+      | Some req ->
+          let now  = now ctx
+          do! Data.addHistory reqId usrId { asOf = now; status = Prayed; text = None } db
+          let nextShow =
+            match Recurrence.duration req.recurType with
+            | 0L       -> Instant.MinValue
+            | duration -> now.Plus (Duration.FromSeconds (duration * int64 req.recurCount))
+          do! Data.updateShowAfter reqId usrId nextShow db
+          do! db.saveChanges ()
+          return! (withSuccessMessage "Request marked as prayed" >=> Components.journalItems) next ctx
+      | None -> return! Error.notFound next ctx
+      }
+  
+  /// POST /request/[req-id]/note
+  let addNote requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let db    = db     ctx
+      let usrId = userId ctx
+      let reqId = RequestId.ofString requestId
+      match! Data.tryRequestById reqId usrId db with
+      | Some _ ->
+          let! notes = ctx.BindFormAsync<Models.NoteEntry> ()
+          do! Data.addNote reqId usrId { asOf = now ctx; notes = notes.notes } db
+          do! db.saveChanges ()
+          return! (withSuccessMessage "Added Notes" >=> hideModal "notes" >=> created) next ctx
+      | None -> return! Error.notFound next ctx
+      }
+          
+  // GET /requests/active
+  let active : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let! reqs = Data.journalByUserId (userId ctx) (db ctx)
+      return! partial "Active Requests" (Views.Request.active (now ctx) reqs) next ctx
+      }
+  
+  // GET /requests/snoozed
+  let snoozed : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let! reqs    = Data.journalByUserId (userId ctx) (db ctx)
+      let  now     = now ctx
+      let  snoozed = reqs |> List.filter (fun it -> it.snoozedUntil > now)
+      return! partial "Active Requests" (Views.Request.snoozed now snoozed) next ctx
+      }
+
+  // GET /requests/answered
+  let answered : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let! reqs = Data.answeredRequests (userId ctx) (db ctx)
+      return! partial "Answered Requests" (Views.Request.answered (now ctx) reqs) next ctx
+      }
+  
+  // GET /api/request/[req-id]
+  let get requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      match! Data.tryJournalById (RequestId.ofString requestId) (userId ctx) (db ctx) with
+      | Some req -> return! json req next ctx
+      | None -> return! Error.notFound next ctx
+      }
+  
+  // GET /request/[req-id]/full
+  let getFull requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      match! Data.tryFullRequestById (RequestId.ofString requestId) (userId ctx) (db ctx) with
+      | Some req -> return! partial "Prayer Request" (Views.Request.full (clock ctx) req) next ctx
+      | None     -> return! Error.notFound next ctx
+      }
+  
+  // PATCH /request/[req-id]/show
+  let show requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let db    = db     ctx
+      let usrId = userId ctx
+      let reqId = RequestId.ofString requestId
+      match! Data.tryRequestById reqId usrId db with
+      | Some _ ->
+          do! Data.updateShowAfter reqId usrId Instant.MinValue db
+          do! db.saveChanges ()
+          return! (withSuccessMessage "Request now shown" >=> Components.requestItem requestId) next ctx
+      | None -> return! Error.notFound next ctx
+      }
+  
+  // PATCH /request/[req-id]/snooze
+  let snooze requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let db    = db     ctx
+      let usrId = userId ctx
+      let reqId = RequestId.ofString requestId
+      match! Data.tryRequestById reqId usrId db with
+      | Some _ ->
+          let! until = ctx.BindFormAsync<Models.SnoozeUntil> ()
+          let date =
+            LocalDatePattern.CreateWithInvariantCulture("yyyy-MM-dd").Parse(until.until).Value
+              .AtStartOfDayInZone(DateTimeZone.Utc)
+              .ToInstant ()
+          do! Data.updateSnoozed reqId usrId date db
+          do! db.saveChanges ()
+          return!
+            (withSuccessMessage $"Request snoozed until {until.until}"
+             >=> hideModal "snooze"
+             >=> Components.journalItems) next ctx
+      | None -> return! Error.notFound next ctx
+      }
+  
+  // PATCH /request/[req-id]/cancel-snooze
+  let cancelSnooze requestId : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let db    = db     ctx
+      let usrId = userId ctx
+      let reqId = RequestId.ofString requestId
+      match! Data.tryRequestById reqId usrId db with
+      | Some _ ->
+          do! Data.updateSnoozed reqId usrId Instant.MinValue db
+          do! db.saveChanges ()
+          return! (withSuccessMessage "Request unsnoozed" >=> Components.requestItem requestId) next ctx
+      | None -> return! Error.notFound next ctx
+      }
+
+  /// Derive a recurrence and interval from its primitive representation in the form
+  let private parseRecurrence (form : Models.Request) =
+    (Recurrence.ofString (match form.recurInterval with Some x -> x | _ -> "Immediate"),
+     defaultArg form.recurCount (int16 0))
+
+  // POST /request
+  let add : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let! form             = ctx.BindModelAsync<Models.Request> ()
+      let  db               = db ctx
+      let  usrId            = userId ctx
+      let  now              = now ctx
+      let (recur, interval) = parseRecurrence form
+      let  req   =
+        { Request.empty with
+            userId     = usrId
+            enteredOn  = now
+            showAfter  = Instant.MinValue
+            recurType  = recur
+            recurCount = interval
+            history    = [
+              { asOf   = now
+                status = Created
+                text   = Some form.requestText
+                }      
+              ]
+          }
+      Data.addRequest req db
+      do! db.saveChanges ()
+      Messages.pushSuccess ctx "Added prayer request" "/journal"
+      return! seeOther "/journal" next ctx
+      }
+  
+  // PATCH /request
+  let update : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> backgroundTask {
+      let! form  = ctx.BindModelAsync<Models.Request> ()
+      let  db    = db ctx
+      let  usrId = userId ctx
+      match! Data.tryJournalById (RequestId.ofString form.requestId) usrId db with
+      | Some req ->
+          // update recurrence if changed
+          let (recur, interval) = parseRecurrence form
+          match recur = req.recurType && interval = req.recurCount with
+          | true  -> ()
+          | false ->
+              do! Data.updateRecurrence req.requestId usrId recur interval db
+              match recur with
+              | Immediate -> do! Data.updateShowAfter req.requestId usrId Instant.MinValue db
+              | _         -> ()
+          // append history
+          let upd8Text = form.requestText.Trim ()
+          let text     = match upd8Text = req.text with true -> None | false -> Some upd8Text
+          do! Data.addHistory req.requestId usrId
+                { asOf = now ctx; status = (Option.get >> RequestAction.ofString) form.status; text = text } db
+          do! db.saveChanges ()
+          let nextUrl =
+            match form.returnTo with
+            | "active"          -> "/requests/active"
+            | "snoozed"         -> "/requests/snoozed"
+            | _ (* "journal" *) -> "/journal"
+          Messages.pushSuccess ctx "Prayer request updated successfully" nextUrl
+          return! seeOther nextUrl next ctx
+      | None -> return! Error.notFound next ctx
+      }
+
+
+/// Handlers for /user URLs
+module User =
+
+  open Microsoft.AspNetCore.Authentication.Cookies
+
+  // GET /user/log-on
+  let logOn : HttpHandler =
+    logOn (Some "/journal")
+  
+  // GET /user/log-off
+  let logOff : HttpHandler =
+    requiresAuthentication Error.notAuthorized
+    >=> fun next ctx -> task {
+      do! ctx.SignOutAsync ("Auth0", AuthenticationProperties (RedirectUri = "/"))
+      do! ctx.SignOutAsync CookieAuthenticationDefaults.AuthenticationScheme
+      return! next ctx
+    }
+
+
+open Giraffe.EndpointRouting
+
+/// The routes for myPrayerJournal
+let routes =
+  [ GET_HEAD [ route "/" Home.home ]
+    subRoute "/components/" [
+      GET_HEAD [
+        route  "journal-items"        Components.journalItems
+        routef "request/%s/add-notes" Components.addNotes
+        routef "request/%s/item"      Components.requestItem
+        routef "request/%s/notes"     Components.notes
+        routef "request/%s/snooze"    Components.snooze
+        ]
+      ]
+    GET_HEAD [ route "/journal" Journal.journal ]
+    subRoute "/legal/" [
+      GET_HEAD [
+        route "privacy-policy"   Legal.privacyPolicy
+        route "terms-of-service" Legal.termsOfService
+        ]
+      ]
+    subRoute "/request" [
+      GET_HEAD [
+        routef "/%s/edit"   Request.edit
+        routef "/%s/full"   Request.getFull
+        route  "s/active"   Request.active
+        route  "s/answered" Request.answered
+        route  "s/snoozed"  Request.snoozed
+        ]
+      PATCH [
+        route  ""                  Request.update
+        routef "/%s/cancel-snooze" Request.cancelSnooze
+        routef "/%s/prayed"        Request.prayed
+        routef "/%s/show"          Request.show
+        routef "/%s/snooze"        Request.snooze
+        ]
+      POST [
+        route  ""         Request.add
+        routef "/%s/note" Request.addNote
+        ]
+      ]
+    subRoute "/user/" [
+      GET_HEAD [
+        route "log-off" User.logOff
+        route "log-on"  User.logOn
+        ]
+      ]
+    ]

src/MyPrayerJournal/MyPrayerJournal.fsproj

@@ -0,0 +1,33 @@
+<Project Sdk="Microsoft.NET.Sdk.Web">
+  <PropertyGroup>
+    <TargetFramework>net6.0</TargetFramework>
+    <Version>3.0.0.0</Version>
+  </PropertyGroup>
+  <ItemGroup>
+    <Compile Include="Domain.fs" />
+    <Compile Include="Data.fs" />
+    <Compile Include="Dates.fs" />
+    <Compile Include="Views/Helpers.fs" />
+    <Compile Include="Views/Journal.fs" />
+    <Compile Include="Views/Layout.fs" />
+    <Compile Include="Views/Legal.fs" />
+    <Compile Include="Views/Request.fs" />
+    <Compile Include="Handlers.fs" />
+    <Compile Include="Program.fs" />
+  </ItemGroup>
+  <ItemGroup>
+    <PackageReference Include="FSharp.SystemTextJson" Version="0.17.4" />
+    <PackageReference Include="FunctionalCuid" Version="1.0.0" />
+    <PackageReference Include="Giraffe" Version="5.0.0" />
+    <PackageReference Include="LiteDB" Version="5.0.11" />
+    <PackageReference Include="Microsoft.AspNetCore.Authentication.OpenIdConnect" Version="5.0.10" />
+    <PackageReference Include="NodaTime" Version="3.0.9" />
+  </ItemGroup>
+  <ItemGroup>
+    <ProjectReference Include="../../../Giraffe.Htmx/src/Htmx/Giraffe.Htmx.fsproj" />
+    <ProjectReference Include="../../../Giraffe.Htmx/src/ViewEngine.Htmx/Giraffe.ViewEngine.Htmx.fsproj" />
+  </ItemGroup>
+  <ItemGroup>
+    <Folder Include="wwwroot\" />
+  </ItemGroup>
+</Project>

src/MyPrayerJournal/Program.fs

@@ -0,0 +1,181 @@
+module MyPrayerJournal.Api
+
+open Microsoft.AspNetCore.Builder
+open Microsoft.AspNetCore.Hosting
+open System.IO
+
+/// Configuration functions for the application
+module Configure =
+  
+  /// Configure the content root
+  let contentRoot root =
+    WebApplicationOptions (ContentRootPath = root) |> WebApplication.CreateBuilder
+
+
+  open Microsoft.Extensions.Configuration
+
+  /// Configure the application configuration
+  let appConfiguration (bldr : WebApplicationBuilder) =
+    bldr.Configuration
+      .SetBasePath(bldr.Environment.ContentRootPath)
+      .AddJsonFile("appsettings.json", optional = false, reloadOnChange = true)
+      .AddJsonFile($"appsettings.{bldr.Environment.EnvironmentName}.json", optional = true, reloadOnChange = true)
+      .AddEnvironmentVariables ()
+    |> ignore
+    bldr
+
+
+  open Microsoft.AspNetCore.Server.Kestrel.Core
+
+  /// Configure Kestrel from appsettings.json
+  let kestrel (bldr : WebApplicationBuilder) =
+    let kestrelOpts (ctx : WebHostBuilderContext) (opts : KestrelServerOptions) =
+      (ctx.Configuration.GetSection >> opts.Configure >> ignore) "Kestrel"
+    bldr.WebHost.UseKestrel().ConfigureKestrel kestrelOpts |> ignore
+    bldr
+
+
+  /// Configure the web root directory
+  let webRoot pathSegments (bldr : WebApplicationBuilder) =
+    Array.concat [ [| bldr.Environment.ContentRootPath |]; pathSegments ]
+    |> (Path.Combine >> bldr.WebHost.UseWebRoot >> ignore)
+    bldr
+
+
+  open Microsoft.Extensions.Logging
+  open Microsoft.Extensions.Hosting
+
+  /// Configure logging
+  let logging (bldr : WebApplicationBuilder) =
+    match bldr.Environment.IsDevelopment () with
+    | true -> ()
+    | false -> bldr.Logging.AddFilter (fun l -> l > LogLevel.Information) |> ignore
+    bldr.Logging.AddConsole().AddDebug() |> ignore
+    bldr
+
+
+  open Giraffe
+  open LiteDB
+  open Microsoft.AspNetCore.Authentication.Cookies
+  open Microsoft.AspNetCore.Authentication.OpenIdConnect
+  open Microsoft.AspNetCore.Http
+  open Microsoft.Extensions.DependencyInjection
+  open Microsoft.IdentityModel.Protocols.OpenIdConnect
+  open NodaTime
+  open System
+  open System.Text.Json
+  open System.Text.Json.Serialization
+  open System.Threading.Tasks
+
+  /// Configure dependency injection
+  let services (bldr : WebApplicationBuilder) =
+    let sameSite (opts : CookieOptions) =
+      match opts.SameSite, opts.Secure with
+      | SameSiteMode.None, false -> opts.SameSite <- SameSiteMode.Unspecified
+      | _, _ -> ()
+
+    bldr.Services
+      .AddRouting()
+      .AddGiraffe()
+      .AddSingleton<IClock>(SystemClock.Instance)
+      .Configure<CookiePolicyOptions>(
+        fun (opts : CookiePolicyOptions) ->
+          opts.MinimumSameSitePolicy <- SameSiteMode.Unspecified
+          opts.OnAppendCookie        <- fun ctx -> sameSite ctx.CookieOptions
+          opts.OnDeleteCookie        <- fun ctx -> sameSite ctx.CookieOptions)
+      .AddAuthentication(
+        /// Use HTTP "Bearer" authentication with JWTs
+        fun opts ->
+          opts.DefaultAuthenticateScheme <- CookieAuthenticationDefaults.AuthenticationScheme
+          opts.DefaultSignInScheme       <- CookieAuthenticationDefaults.AuthenticationScheme
+          opts.DefaultChallengeScheme    <- CookieAuthenticationDefaults.AuthenticationScheme)
+      .AddCookie()
+      .AddOpenIdConnect("Auth0",
+        /// Configure OIDC with Auth0 options from configuration
+        fun opts ->
+          let cfg = bldr.Configuration.GetSection "Auth0"
+          opts.Authority    <- sprintf "https://%s/" cfg["Domain"]
+          opts.ClientId     <- cfg["Id"]
+          opts.ClientSecret <- cfg["Secret"]
+          opts.ResponseType <- OpenIdConnectResponseType.Code
+          
+          opts.Scope.Clear ()
+          opts.Scope.Add "openid"
+          opts.Scope.Add "profile"
+
+          opts.CallbackPath <- PathString "/user/log-on/success"
+          opts.ClaimsIssuer <- "Auth0"
+          opts.SaveTokens   <- true
+
+          opts.Events <- OpenIdConnectEvents ()
+          opts.Events.OnRedirectToIdentityProviderForSignOut <- fun ctx ->
+            let returnTo =
+              match ctx.Properties.RedirectUri with
+              | it when isNull it || it = "" -> ""
+              | redirUri ->
+                  let finalRedirUri =
+                    match redirUri.StartsWith "/" with
+                    | true ->
+                        // transform to absolute
+                        let request = ctx.Request
+                        sprintf "%s://%s%s%s" request.Scheme request.Host.Value request.PathBase.Value redirUri
+                    | false -> redirUri
+                  Uri.EscapeDataString finalRedirUri |> sprintf "&returnTo=%s"
+            sprintf "https://%s/v2/logout?client_id=%s%s" cfg["Domain"] cfg["Id"] returnTo
+            |> ctx.Response.Redirect
+            ctx.HandleResponse ()
+
+            Task.CompletedTask
+          opts.Events.OnRedirectToIdentityProvider <- fun ctx ->
+            let bldr = UriBuilder ctx.ProtocolMessage.RedirectUri
+            bldr.Scheme <- cfg["Scheme"]
+            bldr.Port   <- int cfg["Port"]
+            ctx.ProtocolMessage.RedirectUri <- string bldr
+            Task.CompletedTask
+          )
+    |> ignore
+    let jsonOptions = JsonSerializerOptions ()
+    jsonOptions.Converters.Add (JsonFSharpConverter ())
+    let db = new LiteDatabase (bldr.Configuration.GetConnectionString "db")
+    Data.Startup.ensureDb db
+    bldr.Services.AddSingleton(jsonOptions)
+      .AddSingleton<Json.ISerializer, SystemTextJson.Serializer>()
+      .AddSingleton<LiteDatabase> db
+    |> ignore
+    bldr.Build ()
+  
+
+  open Giraffe.EndpointRouting
+
+  /// Configure the web application
+  let application (app : WebApplication) =
+    // match app.Environment.IsDevelopment () with
+    // | true -> app.UseDeveloperExceptionPage ()
+    // | false -> app.UseGiraffeErrorHandler Handlers.Error.error
+    // |> ignore
+    app
+      .UseStaticFiles()
+      .UseCookiePolicy()
+      .UseRouting()
+      .UseAuthentication()
+      .UseGiraffeErrorHandler(Handlers.Error.error)
+      .UseEndpoints (fun e -> e.MapGiraffeEndpoints Handlers.routes |> ignore)
+    |> ignore
+    app
+
+  /// Compose all the configurations into one
+  let webHost pathSegments =
+    contentRoot
+    >> appConfiguration
+    >> kestrel
+    >> webRoot pathSegments
+    >> logging
+    >> services
+    >> application
+
+
+[<EntryPoint>]
+let main _ =
+  use host = Configure.webHost [| "wwwroot" |] (Directory.GetCurrentDirectory ())
+  host.Run ()
+  0

src/MyPrayerJournal/Properties/launchSettings.json

@@ -0,0 +1,27 @@
+{
+  "iisSettings": {
+    "windowsAuthentication": false,
+    "anonymousAuthentication": true,
+    "iisExpress": {
+      "applicationUrl": "http://localhost:61905",
+      "sslPort": 0
+    }
+  },
+  "profiles": {
+    "IIS Express": {
+      "commandName": "IISExpress",
+      "launchBrowser": true,
+      "environmentVariables": {
+        "ASPNETCORE_ENVIRONMENT": "Development"
+      }
+    },
+    "MyPrayerJournal.Api": {
+      "commandName": "Project",
+      "launchBrowser": true,
+      "applicationUrl": "http://localhost:5000",
+      "environmentVariables": {
+        "ASPNETCORE_ENVIRONMENT": "Development"
+      }
+    }
+  }
+}

src/MyPrayerJournal/Views/Helpers.fs

@@ -0,0 +1,31 @@
+/// Internal partial views
+[<AutoOpen>]
+module private MyPrayerJournal.Views.Helpers
+  
+open Giraffe.ViewEngine
+open Giraffe.ViewEngine.Htmx
+open MyPrayerJournal
+open NodaTime
+
+/// Create a link that targets the `#top` element and pushes a URL to history
+let pageLink href attrs =
+  attrs
+  |> List.append [ _href href; _hxBoost; _hxTarget "#top"; _hxSwap HxSwap.InnerHtml; _hxPushUrl ]
+  |> a
+
+/// Create a Material icon
+let icon name = span [ _class "material-icons" ] [ str name ]
+
+/// Create a card when there are no results found
+let noResults heading link buttonText text =
+  div [ _class "card" ] [
+    h5 [ _class "card-header"] [ str heading ]
+    div [ _class "card-body text-center" ] [
+      p [ _class "card-text" ] text
+      pageLink link [ _class "btn btn-primary" ] [ str buttonText ]
+      ]
+    ]
+
+/// Create a date with a span tag, displaying the relative date with the full date/time in the tooltip
+let relativeDate (date : Instant) now =
+  span [ _title (date.ToDateTimeOffset().ToString ("f", null)) ] [ Dates.formatDistance now date |> str ]

src/MyPrayerJournal/Views/Journal.fs

@@ -0,0 +1,177 @@
+/// Views for journal pages and components
+module MyPrayerJournal.Views.Journal
+
+open Giraffe.ViewEngine
+open Giraffe.ViewEngine.Accessibility
+open Giraffe.ViewEngine.Htmx
+open MyPrayerJournal
+
+/// Display a card for this prayer request
+let journalCard now req =
+  let reqId = RequestId.toString req.requestId
+  let spacer = span [] [ rawText " " ]
+  div [ _class "col" ] [
+    div [ _class "card h-100" ] [
+      div [ _class "card-header p-0 d-flex"; _roleToolBar ] [
+        pageLink $"/request/{reqId}/edit" [ _class  "btn btn-secondary"; _title "Edit Request" ] [ icon "edit" ]
+        spacer
+        button [
+          _type     "button"
+          _class    "btn btn-secondary"
+          _title    "Add Notes"
+          _data     "bs-toggle" "modal"
+          _data     "bs-target" "#notesModal"
+          _hxGet    $"/components/request/{reqId}/add-notes"
+          _hxTarget "#notesBody"
+          _hxSwap   HxSwap.InnerHtml
+          ] [ icon "comment" ]
+        spacer
+        button [
+          _type     "button"
+          _class    "btn btn-secondary"
+          _title    "Snooze Request"
+          _data     "bs-toggle" "modal"
+          _data     "bs-target" "#snoozeModal"
+          _hxGet    $"/components/request/{reqId}/snooze"
+          _hxTarget "#snoozeBody"
+          _hxSwap   HxSwap.InnerHtml
+          ] [ icon "schedule" ]
+        div [ _class "flex-grow-1" ] []
+        button [
+          _type    "button"
+          _class   "btn btn-success w-25"
+          _hxPatch $"/request/{reqId}/prayed"
+          _title   "Mark as Prayed"
+          ] [ icon "done" ]
+        ]
+      div [ _class "card-body" ] [
+        p [ _class "request-text" ] [ str req.text ]
+        ]
+      div [ _class "card-footer text-end text-muted px-1 py-0" ] [
+        em [] [ str "last activity "; relativeDate req.asOf now ]
+        ]
+      ]
+    ]
+
+/// The journal loading page
+let journal user = article [ _class "container-fluid mt-3" ] [
+  h2 [ _class "pb-3" ] [
+    str user
+    match user with "Your" -> () | _ -> rawText "’s"
+    str " Prayer Journal"
+    ]
+  p [ _class "pb-3 text-center" ] [
+    pageLink "/request/new/edit" [ _class "btn btn-primary "] [ icon "add_box"; str " Add a Prayer Request" ]
+    ]
+  p [ _hxGet "/components/journal-items"; _hxSwap HxSwap.OuterHtml; _hxTrigger HxTrigger.Load ] [
+    rawText "Loading your prayer journal…"
+    ]
+  div [
+    _id             "notesModal"
+    _class          "modal fade"
+    _tabindex       "-1"
+    _ariaLabelledBy "nodesModalLabel"
+    _ariaHidden     "true"
+    ] [
+    div [ _class "modal-dialog modal-dialog-scrollable" ] [
+      div [ _class "modal-content" ] [
+        div [ _class "modal-header" ] [
+          h5 [ _class "modal-title"; _id "nodesModalLabel" ] [ str "Add Notes to Prayer Request" ]
+          button [ _type "button"; _class "btn-close"; _data "bs-dismiss" "modal"; _ariaLabel "Close" ] []
+          ]
+        div [ _class "modal-body"; _id "notesBody" ] [ ]
+        div [ _class "modal-footer" ] [
+          button [ _type "button"; _id "notesDismiss"; _class "btn btn-secondary"; _data "bs-dismiss" "modal" ] [
+            str "Close"
+            ]
+          ]
+        ]
+      ]
+    ]
+  div [
+    _id             "snoozeModal"
+    _class          "modal fade"
+    _tabindex       "-1"
+    _ariaLabelledBy "snoozeModalLabel"
+    _ariaHidden     "true"
+    ] [
+    div [ _class "modal-dialog modal-sm" ] [
+      div [ _class "modal-content" ] [
+        div [ _class "modal-header" ] [
+          h5 [ _class "modal-title"; _id "snoozeModalLabel" ] [ str "Snooze Prayer Request" ]
+          button [ _type "button"; _class "btn-close"; _data "bs-dismiss" "modal"; _ariaLabel "Close" ] []
+          ]
+        div [ _class "modal-body"; _id "snoozeBody" ] [ ]
+        div [ _class "modal-footer" ] [
+          button [ _type "button"; _id "snoozeDismiss"; _class "btn btn-secondary"; _data "bs-dismiss" "modal" ] [
+            str "Close"
+            ]
+          ]
+        ]
+      ]
+    ]
+  ]
+
+/// The journal items
+let journalItems now items =
+  match items |> List.isEmpty with
+  | true ->
+      noResults "No Active Requests" "/request/new/edit" "Add a Request" [
+        rawText "You have no requests to be shown; see the “Active” link above for snoozed or deferred "
+        rawText "requests, and the “Answered” link for answered requests"
+        ]
+  | false ->
+      items
+      |> List.map (journalCard now)
+      |> section [
+          _id       "journalItems"
+          _class    "row row-cols-1 row-cols-md-2 row-cols-lg-3 row-cols-xl-4 g-3"
+          _hxTarget "this"
+          _hxSwap   HxSwap.OuterHtml
+          ]
+
+/// The notes edit modal body
+let notesEdit requestId =
+  let reqId = RequestId.toString requestId
+  [ form [ _hxPost $"/request/{reqId}/note" ] [
+      div [ _class "form-floating pb-3" ] [
+        textarea [
+          _id          "notes"
+          _name        "notes"
+          _class       "form-control"
+          _style       "min-height: 8rem;"
+          _placeholder "Notes"
+          _autofocus;  _required
+          ] [ ]
+        label [ _for "notes" ] [ str "Notes" ]
+        ]
+      p [ _class "text-end" ] [ button [ _type "submit"; _class "btn btn-primary" ] [ str "Add Notes" ] ]
+      ]
+    hr [ _style "margin: .5rem -1rem" ]
+    div [ _id "priorNotes" ] [
+      p [ _class "text-center pt-3" ] [
+        button [
+          _type     "button"
+          _class    "btn btn-secondary"
+          _hxGet    $"/components/request/{reqId}/notes"
+          _hxSwap   HxSwap.OuterHtml
+          _hxTarget "#priorNotes"
+          ] [str "Load Prior Notes" ]
+        ]
+      ]
+    ]
+
+/// The snooze edit form
+let snooze requestId =
+  let today = System.DateTime.Today.ToString "yyyy-MM-dd"
+  form [
+    _hxPatch  $"/request/{RequestId.toString requestId}/snooze"
+    _hxTarget "#journalItems"
+    _hxSwap   HxSwap.OuterHtml
+    ] [
+    div [ _class "form-floating pb-3" ] [
+      input [ _type "date"; _id "until"; _name "until"; _class "form-control"; _min today; _required ]
+      label [ _for "until" ] [ str "Until" ]
+      ]
+    p [ _class "text-end mb-0" ] [ button [ _type "submit"; _class "btn btn-primary" ] [ str "Snooze" ] ]
+    ]

src/MyPrayerJournal/Views/Layout.fs

@@ -0,0 +1,151 @@
+/// Layout / home views
+module MyPrayerJournal.Views.Layout
+
+// fsharplint:disable RecordFieldNames
+
+open Giraffe.ViewEngine
+open Giraffe.ViewEngine.Accessibility
+
+/// The data needed to render a page-level view
+type PageRenderContext = {
+  /// Whether the user is authenticated
+  isAuthenticated : bool
+  /// Whether the user has snoozed requests
+  hasSnoozed      : bool
+  /// The current URL
+  currentUrl      : string
+  /// The title for the page to be rendered
+  pageTitle       : string
+  /// The content of the page
+  content         : XmlNode
+  }
+
+/// The home page
+let home = article [ _class "container mt-3" ] [
+  p [] [ rawText " " ]
+  p [] [
+    str "myPrayerJournal is a place where individuals can record their prayer requests, record that they prayed for "
+    str "them, update them as God moves in the situation, and record a final answer received on that request. It also "
+    str "allows individuals to review their answered prayers."
+    ]
+  p [] [
+    str "This site is open and available to the general public. To get started, simply click the "
+    rawText "“Log On” link above, and log on with either a Microsoft or Google account. You can also "
+    rawText "learn more about the site at the “Docs” link, also above."
+    ]
+  ]
+
+/// The default navigation bar, which will load the items on page load, and whenever a refresh event occurs
+let private navBar ctx =
+  nav [ _class "navbar navbar-dark"; _roleNavigation ] [
+    div [ _class "container-fluid" ] [
+      pageLink "/" [ _class "navbar-brand" ] [
+        span [ _class "m" ] [ str "my" ]
+        span [ _class "p" ] [ str "Prayer" ]
+        span [ _class "j" ] [ str "Journal" ]
+      ]
+      seq {
+        let navLink (matchUrl : string) =
+          match ctx.currentUrl.StartsWith matchUrl with true -> [ _class "is-active-route" ] | false -> []
+          |> pageLink matchUrl
+        match ctx.isAuthenticated with
+        | true ->
+            li [ _class "nav-item" ] [ navLink "/journal" [ str "Journal" ] ]
+            li [ _class "nav-item" ] [ navLink "/requests/active" [ str "Active" ] ]
+            if ctx.hasSnoozed then li [ _class "nav-item" ] [ navLink "/requests/snoozed" [ str "Snoozed" ] ]
+            li [ _class "nav-item" ] [ navLink "/requests/answered" [ str "Answered" ] ]
+            li [ _class "nav-item" ] [ a [ _href "/user/log-off" ] [ str "Log Off" ] ]
+        | false -> li [ _class "nav-item"] [ a [ _href "/user/log-on" ] [ str "Log On" ] ]
+        li [ _class "nav-item" ] [
+          a [ _href "https://docs.prayerjournal.me"; _target "_blank"; _rel "noopener" ] [ str "Docs" ]
+          ]
+        }
+      |> List.ofSeq
+      |> ul [ _class "navbar-nav me-auto d-flex flex-row" ]
+      ]
+    ]
+
+/// The title tag with the application name appended
+let titleTag ctx = title [] [ str ctx.pageTitle; rawText " « myPrayerJournal" ]
+
+/// The HTML `head` element
+let htmlHead ctx =
+  head [ _lang "en" ] [
+    meta [ _name "viewport"; _content "width=device-width, initial-scale=1" ]
+    meta [ _name "description"; _content "Online prayer journal - free w/Google or Microsoft account" ]
+    titleTag ctx
+    link [
+      _href        "https://cdn.jsdelivr.net/npm/bootstrap@5.0.2/dist/css/bootstrap.min.css"
+      _rel         "stylesheet"
+      _integrity   "sha384-EVSTQN3/azprG1Anm3QDgpJLIm9Nao0Yz1ztcQTwFspd3yD65VohhpuuCOmLASjC"
+      _crossorigin "anonymous"
+      ]
+    link [ _href "https://fonts.googleapis.com/icon?family=Material+Icons"; _rel "stylesheet" ]
+    link [ _href "/style/style.css"; _rel "stylesheet" ]
+    ]
+
+/// Element used to display toasts
+let toaster =
+  div [ _ariaLive "polite"; _ariaAtomic "true"; _id "toastHost" ] [
+    div [ _class "toast-container position-absolute p-3 bottom-0 end-0"; _id "toasts" ] []
+  ]
+
+/// The page's `footer` element
+let htmlFoot =
+  footer [ _class "container-fluid" ] [
+    p [ _class "text-muted text-end" ] [
+      str "myPrayerJournal v3"
+      br []
+      em [] [
+        small [] [
+          pageLink "/legal/privacy-policy" [] [ str "Privacy Policy" ]
+          rawText " • "
+          pageLink "/legal/terms-of-service" [] [ str "Terms of Service" ]
+          rawText " • "
+          a [ _href "https://github.com/bit-badger/myprayerjournal"; _target "_blank"; _rel "noopener" ] [
+            str "Developed"
+            ]
+          str " and hosted by "
+          a [ _href "https://bitbadger.solutions"; _target "_blank"; _rel "noopener" ] [ str "Bit Badger Solutions" ]
+          ]
+        ]
+      ]
+    script [
+      _src         "https://unpkg.com/htmx.org@1.5.0"
+      _integrity   "sha384-oGA+prIp5Vchu6we2YkI51UtVzN9Jpx2Z7PnR1I78PnZlN8LkrCT4lqqqmDkyrvI"
+      _crossorigin "anonymous"
+      ] []
+    script [] [
+      rawText "if (!htmx) document.write('<script src=\"/script/htmx-1.5.0.min.js\"><\/script>')"
+      ]
+    script [
+      _async
+      _src         "https://cdn.jsdelivr.net/npm/bootstrap@5.0.2/dist/js/bootstrap.bundle.min.js"
+      _integrity   "sha384-MrcW6ZMFYlzcLA8Nl+NtUVF0sA7MsXsP1UyJoMp4YLEuNSfAP+JcXn/tWtIaxVXM"
+      _crossorigin "anonymous"
+      ] []
+    script [] [
+      rawText "setTimeout(function () { "
+      rawText "if (!bootstrap) document.write('<script src=\"/script/bootstrap.bundle.min.js\"><\/script>') "
+      rawText "}, 2000)"
+      ]
+    script [ _src "/script/mpj.js" ] []
+    ]
+
+/// Create the full view of the page
+let view ctx =
+  html [ _lang "en" ] [
+    htmlHead ctx
+    body [] [
+      section [ _id "top" ] [ navBar ctx; main [ _roleMain ] [ ctx.content ] ]
+      toaster
+      htmlFoot
+      ]
+    ]
+
+/// Create a partial view
+let partial ctx =
+  html [ _lang "en" ] [
+    head [] [ titleTag ctx ]
+    body [] [ navBar ctx; main [ _roleMain ] [ ctx.content ] ]
+    ]

src/MyPrayerJournal/Views/Legal.fs

@@ -0,0 +1,153 @@
+/// Views for legal pages
+module MyPrayerJournal.Views.Legal
+
+open Giraffe.ViewEngine
+
+/// View for the "Privacy Policy" page
+let privacyPolicy = article [ _class "container mt-3" ] [
+  h2 [ _class "mb-2" ] [ str "Privacy Policy" ]
+  h6 [ _class "text-muted pb-3" ] [ str "as of May 21"; sup [] [ str "st"]; str ", 2018" ]
+  p [] [
+    str "The nature of the service is one where privacy is a must. The items below will help you understand the data "
+    str "we collect, access, and store on your behalf as you use this service."
+    ]
+  div [ _class "card" ] [
+    div [ _class "list-group list-group-flush" ] [
+      div [ _class "list-group-item"] [
+        h3 [] [ str "Third Party Services" ]
+        p [ _class "card-text" ] [
+          str "myPrayerJournal utilizes a third-party authentication and identity provider. You should familiarize "
+          str "yourself with the privacy policy for "
+          a [ _href "https://auth0.com/privacy"; _target "_blank" ] [ str "Auth0" ]
+          str ", as well as your chosen provider ("
+          a [ _href "https://privacy.microsoft.com/en-us/privacystatement"; _target "_blank" ] [ str "Microsoft"]
+          str " or "
+          a [ _href "https://policies.google.com/privacy"; _target "_blank" ] [ str "Google" ]
+          str ")."
+          ]
+        ]
+      div [ _class "list-group-item" ] [
+        h3 [] [ str "What We Collect" ]
+        h4 [] [ str "Identifying Data" ]
+        ul [] [
+          li [] [
+            rawText "The only identifying data myPrayerJournal stores is the subscriber (“sub”) field from "
+            str "the token we receive from Auth0, once you have signed in through their hosted service. All "
+            str "information is associated with you via this field."
+            ]
+          li [] [
+            str "While you are signed in, within your browser, the service has access to your first and last names, "
+            str "along with a URL to the profile picture (provided by your selected identity provider). This "
+            rawText "information is not transmitted to the server, and is removed when “Log Off” is "
+            str "clicked."
+            ]
+          ]
+        h4 [] [ str "User Provided Data" ]
+        ul [ _class "mb-0" ] [
+          li [] [
+            str "myPrayerJournal stores the information you provide, including the text of prayer requests, updates, "
+            str "and notes; and the date/time when certain actions are taken."
+            ]
+          ]
+        ]
+      div [ _class "list-group-item" ] [
+        h3 [] [ str "How Your Data Is Accessed / Secured" ]
+        ul [ _class "mb-0" ] [
+          li [] [
+            str "Your provided data is returned to you, as required, to display your journal or your answered "
+            str "requests. On the server, it is stored in a controlled-access database."
+            ]
+          li [] [
+            str "Your data is backed up, along with other Bit Badger Solutions hosted systems, in a rolling manner; "
+            str "backups are preserved for the prior 7 days, and backups from the 1"
+            sup [] [ str "st" ]
+            str " and 15"
+            sup [] [ str "th" ]
+            str " are preserved for 3 months. These backups are stored in a private cloud data repository."
+            ]
+          li [] [
+            str "The data collected and stored is the absolute minimum necessary for the functionality of the service. "
+            rawText "There are no plans to “monetize” this service, and storing the minimum amount of "
+            str "information means that the data we have is not interesting to purchasers (or those who may have more "
+            str "nefarious purposes)."
+            ]
+          li [] [
+            str "Access to servers and backups is strictly controlled and monitored for unauthorized access attempts."
+            ]
+          ]
+        ]
+      div [ _class "list-group-item" ] [
+        h3 [] [ str "Removing Your Data" ]
+        p [ _class "card-text" ] [
+          str "At any time, you may choose to discontinue using this service. Both Microsoft and Google provide ways "
+          str "to revoke access from this application. However, if you want your data removed from the database, "
+          str "please contact daniel at bitbadger.solutions (via e-mail, replacing at with @) prior to doing so, to "
+          str "ensure we can determine which subscriber ID belongs to you."
+          ]
+        ]
+      ]
+    ]
+  ]
+
+/// View for the "Terms of Service" page
+let termsOfService = article [ _class "container mt-3" ] [
+  h2 [ _class "mb-2" ] [ str "Terms of Service" ]
+  h6 [ _class "text-muted pb-3"] [ str "as of May 21"; sup [] [ str "st" ]; str ", 2018" ]
+  div [ _class "card" ] [
+    div [ _class "list-group list-group-flush" ] [
+      div [ _class "list-group-item" ] [
+        h3 [] [ str "1. Acceptance of Terms" ]
+        p [ _class "card-text" ] [
+          str "By accessing this web site, you are agreeing to be bound by these Terms and Conditions, and that you "
+          str "are responsible to ensure that your use of this site complies with all applicable laws. Your continued "
+          str "use of this site implies your acceptance of these terms."
+          ]
+        ]
+      div [ _class "list-group-item" ] [
+        h3 [] [ str "2. Description of Service and Registration" ]
+        p [ _class "card-text" ] [
+          str "myPrayerJournal is a service that allows individuals to enter and amend their prayer requests. It "
+          str "requires no registration by itself, but access is granted based on a successful login with an external "
+          str "identity provider. See "
+          pageLink "/legal/privacy-policy" [] [ str "our privacy policy" ]
+          str " for details on how that information is accessed and stored."
+          ]
+        ]
+      div [ _class "list-group-item" ] [
+        h3 [] [ str "3. Third Party Services" ]
+        p [ _class "card-text" ] [
+          str "This service utilizes a third-party service provider for identity management. Review the terms of "
+          str "service for "
+          a [ _href "https://auth0.com/terms"; _target "_blank" ] [ str "Auth0"]
+          str ", as well as those for the selected authorization provider ("
+          a [ _href "https://www.microsoft.com/en-us/servicesagreement"; _target "_blank" ] [ str "Microsoft"]
+          str " or "
+          a [ _href "https://policies.google.com/terms"; _target "_blank" ] [ str "Google" ]
+          str ")."
+          ]
+        ]
+      div [ _class "list-group-item" ] [
+        h3 [] [ str "4. Liability" ]
+        p [ _class "card-text" ] [
+          rawText "This service is provided “as is”, and no warranty (express or implied) exists. The "
+          str "service and its developers may not be held liable for any damages that may arise through the use of "
+          str "this service."
+          ]
+        ]
+      div [ _class "list-group-item" ] [
+        h3 [] [ str "5. Updates to Terms" ]
+        p [ _class "card-text" ] [
+          str "These terms and conditions may be updated at any time, and this service does not have the capability to "
+          str "notify users when these change. The date at the top of the page will be updated when any of the text of "
+          str "these terms is updated."
+          ]
+        ]
+      ]
+    ]
+  p [ _class "pt-3" ] [
+    str "You may also wish to review our "
+    pageLink "/legal/privacy-policy" [] [ str "privacy policy" ]
+    str " to learn how we handle your data."
+    ]
+  ]
+

src/MyPrayerJournal/Views/Request.fs

@@ -0,0 +1,268 @@
+/// Views for request pages and components
+module MyPrayerJournal.Views.Request
+
+open Giraffe.ViewEngine
+open Giraffe.ViewEngine.Htmx
+open MyPrayerJournal
+open NodaTime
+open System
+
+/// Create a request within the list
+let reqListItem now req =
+  let reqId      = RequestId.toString req.requestId
+  let isAnswered = req.lastStatus = Answered
+  let isSnoozed  = req.snoozedUntil > now
+  let isPending  = (not isSnoozed) && req.showAfter > now
+  let btnClass   = _class "btn btn-light mx-2"
+  let restoreBtn (link : string) title =
+    button [ btnClass; _hxPatch $"/request/{reqId}/{link}"; _title title ] [ icon "restore" ]
+  div [ _class "list-group-item px-0 d-flex flex-row align-items-start"; _hxTarget "this"; _hxSwap HxSwap.OuterHtml ] [
+    pageLink $"/request/{reqId}/full" [ btnClass; _title "View Full Request" ] [ icon "description" ]
+    match isAnswered with
+    | true  -> ()
+    | false -> pageLink $"/request/{reqId}/edit" [ btnClass; _title "Edit Request" ] [ icon "edit" ]
+    match true with
+    | _ when isSnoozed -> restoreBtn "cancel-snooze" "Cancel Snooze"
+    | _ when isPending -> restoreBtn "show"          "Show Now"
+    | _ -> ()
+    p [ _class "request-text mb-0" ] [
+      str req.text
+      match isSnoozed || isPending || isAnswered with
+      | true ->
+          br []
+          small [ _class "text-muted" ] [
+            match () with
+            | _ when isSnoozed   -> [ str "Snooze expires ";       relativeDate req.snoozedUntil now ]
+            | _ when isPending   -> [ str "Request appears next "; relativeDate req.showAfter    now ]
+            | _ (* isAnswered *) -> [ str "Answered ";             relativeDate req.asOf         now ]
+            |> em []
+            ]
+      | false -> ()
+      ]
+    ]
+
+/// Create a list of requests
+let reqList now reqs =
+  reqs
+  |> List.map (reqListItem now)
+  |> div [ _class "list-group" ]
+
+/// View for Active Requests page
+let active now reqs = article [ _class "container mt-3" ] [
+  h2 [ _class "pb-3" ] [ str "Active Requests" ]
+  match reqs |> List.isEmpty with
+  | true ->
+      noResults "No Active Requests" "/journal" "Return to your journal"
+        [ str "Your prayer journal has no active requests" ]
+  | false -> reqList now reqs
+  ]
+
+/// View for Answered Requests page
+let answered now reqs = article [ _class "container mt-3" ] [
+  h2 [ _class "pb-3" ] [ str "Answered Requests" ]
+  match reqs |> List.isEmpty with
+  | true ->
+      noResults "No Active Requests" "/journal" "Return to your journal" [
+        rawText "Your prayer journal has no answered requests; once you have marked one as “Answered”, "
+        str "it will appear here"
+        ]
+  | false -> reqList now reqs
+  ]
+
+/// View for Snoozed Requests page
+let snoozed now reqs = article [ _class "container mt-3" ] [
+  h2 [ _class "pb-3" ] [ str "Snoozed Requests" ]
+  reqList now reqs
+  ]
+
+/// View for Full Request page
+let full (clock : IClock) (req : Request) =
+  let now = clock.GetCurrentInstant ()
+  let answered =
+    req.history
+    |> List.filter RequestAction.isAnswered
+    |> List.tryHead
+    |> Option.map (fun x -> x.asOf)
+  let prayed = (req.history |> List.filter RequestAction.isPrayed |> List.length).ToString "N0"
+  let daysOpen =
+    let asOf = defaultArg answered now
+    ((asOf - (req.history |> List.filter RequestAction.isCreated |> List.head).asOf).TotalDays |> int).ToString "N0"
+  let lastText =
+    req.history
+    |> List.filter (fun h -> Option.isSome h.text)
+    |> List.sortByDescending (fun h -> h.asOf)
+    |> List.map (fun h -> Option.get h.text)
+    |> List.head
+  // The history log including notes (and excluding the final entry for answered requests)
+  let log =
+    let toDisp (h : History) = {| asOf = h.asOf; text = h.text; status = RequestAction.toString h.status |}
+    let all =
+      req.notes
+      |> List.map (fun n -> {| asOf = n.asOf; text = Some n.notes; status = "Notes" |})
+      |> List.append (req.history |> List.map toDisp)
+      |> List.sortByDescending (fun it -> it.asOf)
+    // Skip the first entry for answered requests; that info is already displayed
+    match answered with Some _ -> all |> List.skip 1 | None -> all
+  article [ _class "container mt-3" ] [
+    div [_class "card" ] [
+      h5 [ _class "card-header" ] [ str "Full Prayer Request" ]
+      div [ _class "card-body" ] [
+        h6 [ _class "card-subtitle text-muted mb-2"] [
+          match answered with
+          | Some date ->
+              str "Answered "
+              date.ToDateTimeOffset().ToString ("D", null) |> str
+              str " ("
+              relativeDate date now
+              rawText ") • "
+          | None -> ()
+          sprintf "Prayed %s times • Open %s days" prayed daysOpen |> rawText
+          ]
+        p [ _class "card-text" ] [ str lastText ]
+        ]
+      log
+      |> List.map (fun it -> li [ _class "list-group-item" ] [
+        p [ _class "m-0" ] [
+          str it.status
+          rawText "  "
+          small [] [ em [] [ it.asOf.ToDateTimeOffset().ToString ("D", null) |> str ] ]
+          ]
+        match it.text with
+        | Some txt -> p [ _class "mt-2 mb-0" ] [ str txt ]
+        | None -> ()
+      ])
+      |> ul [ _class "list-group list-group-flush" ]
+      ]
+    ]
+
+/// View for the edit request component
+let edit (req : JournalRequest) returnTo isNew =
+  let cancelLink =
+    match returnTo with
+    | "active"          -> "/requests/active"
+    | "snoozed"         -> "/requests/snoozed"
+    | _ (* "journal" *) -> "/journal"
+  article [ _class "container" ] [
+    h2 [ _class "pb-3" ] [ (match isNew with true -> "Add" | false -> "Edit") |> strf "%s Prayer Request" ]
+    form [
+      _hxBoost
+      _hxTarget "#top"
+      _hxPushUrl
+      "/request" |> match isNew with true -> _hxPost | false -> _hxPatch
+      ] [
+      input [
+        _type  "hidden"
+        _name  "requestId"
+        _value (match isNew with true -> "new" | false -> RequestId.toString req.requestId)
+        ]
+      input [ _type "hidden"; _name "returnTo"; _value returnTo ]
+      div [ _class "form-floating pb-3" ] [
+        textarea [
+          _id          "requestText"
+          _name        "requestText"
+          _class       "form-control"
+          _style       "min-height: 8rem;"
+          _placeholder "Enter the text of the request"
+          _autofocus;  _required
+          ] [ str req.text ]
+        label [ _for "requestText" ] [ str "Prayer Request" ]
+        ]
+      br []
+      match isNew with
+      | true -> ()
+      | false ->
+          div [ _class "pb-3" ] [
+            label [] [ str "Also Mark As" ]
+            br []
+            div [ _class "form-check form-check-inline" ] [
+              input [ _type "radio"; _class "form-check-input"; _id "sU"; _name "status"; _value "Updated"; _checked ]
+              label [ _for "sU" ] [ str "Updated" ]
+              ]
+            div [ _class "form-check form-check-inline" ] [
+              input [ _type "radio"; _class "form-check-input"; _id "sP"; _name "status"; _value "Prayed" ]
+              label [ _for "sP" ] [ str "Prayed" ]
+              ]
+            div [ _class "form-check form-check-inline" ] [
+              input [ _type "radio"; _class "form-check-input"; _id "sA"; _name "status"; _value "Answered" ]
+              label [ _for "sA" ] [ str "Answered" ]
+              ]
+            ]
+      div [ _class "row" ] [
+        div [ _class "col-12 offset-md-2 col-md-8 offset-lg-3 col-lg-6" ] [
+          p [] [
+            strong [] [ rawText "Recurrence   " ]
+            em [ _class "text-muted" ] [ rawText "After prayer, request reappears…" ]
+            ]
+          div [ _class "d-flex flex-row flex-wrap justify-content-center align-items-center" ] [
+            div [ _class "form-check mx-2" ] [
+              input [
+                _type    "radio"
+                _class   "form-check-input"
+                _id      "rI"
+                _name    "recurType"
+                _value   "Immediate"
+                _onclick "mpj.edit.toggleRecurrence(event)"
+                match req.recurType with Immediate -> _checked | _ -> ()
+                ]
+              label [ _for "rI" ] [ str "Immediately" ]
+              ]
+            div [ _class "form-check mx-2"] [
+              input [
+                _type    "radio"
+                _class   "form-check-input"
+                _id      "rO"
+                _name    "recurType"
+                _value   "Other"
+                _onclick "mpj.edit.toggleRecurrence(event)"
+                match req.recurType with Immediate -> () | _ -> _checked
+                ]
+              label [ _for "rO" ] [ rawText "Every…" ]
+              ]
+            div [ _class "form-floating mx-2"] [
+              input [
+                _type        "number"
+                _class       "form-control"
+                _id          "recurCount"
+                _name        "recurCount"
+                _placeholder "0"
+                _value       (string req.recurCount)
+                _style       "width:6rem;"
+                _required
+                match req.recurType with Immediate -> _disabled | _ -> ()
+                ]
+              label [ _for "recurCount" ] [ str "Count" ]
+              ]
+            div [ _class "form-floating mx-2" ] [
+              select [
+                _class    "form-control"
+                _id       "recurInterval"
+                _name     "recurInterval"
+                _style    "width:6rem;"
+                _required
+                match req.recurType with Immediate -> _disabled | _ -> ()
+                ] [
+                option [ _value "Hours"; match req.recurType with Hours -> _selected | _ -> () ] [ str "hours" ]
+                option [ _value "Days";  match req.recurType with Days  -> _selected | _ -> () ] [ str "days" ]
+                option [ _value "Weeks"; match req.recurType with Weeks -> _selected | _ -> () ] [ str "weeks" ]
+                ]
+              label [ _form "recurInterval" ] [ str "Interval" ]
+              ]
+            ]
+          ]
+        ]
+      div [ _class "text-end pt-3" ] [
+        button [ _class "btn btn-primary me-2"; _type "submit" ] [ icon "save"; str " Save" ]
+        pageLink cancelLink [ _class "btn btn-secondary ms-2" ] [ icon "arrow_back"; str " Cancel" ]
+        ]
+      ]
+    ]
+
+/// Display a list of notes for a request
+let notes now notes =
+  let toItem (note : Note) =
+    p [] [ small [ _class "text-muted" ] [ relativeDate note.asOf now ]; br []; str note.notes ]
+  [ p [ _class "text-center" ] [ strong [] [ str "Prior Notes for This Request" ] ]
+    match notes with
+    | [] -> p [ _class "text-center text-muted" ] [ str "There are no prior notes for this request" ]
+    | _  -> yield! notes |> List.map toItem
+    ]

src/MyPrayerJournal/appsettings.json

@@ -0,0 +1,12 @@
+{
+  "ConnectionStrings": {
+    "db": "Filename=./mpj.db"
+  },
+  "Kestrel": {
+    "EndPoints": {
+      "Http": {
+        "Url": "http://localhost:3000"
+      }
+    }
+  }
+}

src/MyPrayerJournal/wwwroot/script/mpj.js

@@ -0,0 +1,82 @@
+"use strict"
+
+/** myPrayerJournal script */
+const mpj = {
+  /**
+   * Show a message via toast
+   * @param {string} message The message to show
+   */
+  showToast (message) {
+    const [level, msg] = message.split("|||")
+    
+    let header
+    if (level !== "success") {
+      const heading = typ => `<span class="me-auto"><strong>${typ.toUpperCase()}</strong></span>`
+      
+      header = document.createElement("div")
+      header.className = "toast-header"
+      header.innerHTML = heading(level === "warning" ? level : "error")
+      
+      const close = document.createElement("button")
+      close.type = "button"
+      close.className = "btn-close"
+      close.setAttribute("data-bs-dismiss", "toast")
+      close.setAttribute("aria-label", "Close")
+      header.appendChild(close)
+    }
+
+    const body = document.createElement("div")
+    body.className = "toast-body"
+    body.innerText = msg
+    
+    const toastEl = document.createElement("div")
+    toastEl.className = `toast bg-${level === "error" ? "danger" : level} text-white`
+    toastEl.setAttribute("role", "alert")
+    toastEl.setAttribute("aria-live", "assertlive")
+    toastEl.setAttribute("aria-atomic", "true")
+    toastEl.addEventListener("hidden.bs.toast", e => e.target.remove())
+    if (header) toastEl.appendChild(header)
+    
+    toastEl.appendChild(body)
+    document.getElementById("toasts").appendChild(toastEl)
+    new bootstrap.Toast(toastEl, { autohide: level === "success" }).show()
+  },
+  /**
+   * Load local version of Bootstrap CSS if the CDN load failed
+   */
+  ensureCss () {
+    let loaded = false
+    for (let i = 0; !loaded && i < document.styleSheets.length; i++) {
+      loaded = document.styleSheets[i].href.endsWith("bootstrap.min.css")
+    }
+    if (!loaded) {
+      const css = document.createElement("link")
+      css.rel = "stylesheet"
+      css.href = "/style/bootstrap.min.css"
+      document.getElementsByTagName("head")[0].appendChild(css)
+    }
+  },
+  /** Script for the request edit component */
+  edit: {
+    /**
+     * Toggle the recurrence input fields
+     * @param {Event} e The click event
+     */
+    toggleRecurrence ({ target }) {
+      const isDisabled = target.value === "Immediate"
+      ;["recurCount", "recurInterval"].forEach(it => document.getElementById(it).disabled = isDisabled)
+    }
+  }
+}
+
+htmx.on("htmx:afterOnLoad", function (evt) {
+  const hdrs = evt.detail.xhr.getAllResponseHeaders()
+  // Show a message if there was one in the response
+  if (hdrs.indexOf("x-toast") >= 0) {
+    mpj.showToast(evt.detail.xhr.getResponseHeader("x-toast"))
+  }
+  // Hide a modal window if requested
+  if (hdrs.indexOf("x-hide-modal") >= 0) {
+    document.getElementById(evt.detail.xhr.getResponseHeader("x-hide-modal") + "Dismiss").click()
+  }
+})

src/MyPrayerJournal/wwwroot/style/style.css

@@ -0,0 +1,57 @@
+
+nav {
+  background-color: green;
+}
+nav .m {
+  font-weight: 100;
+}
+nav .p {
+  font-weight: 400;
+}
+nav .j {
+  font-weight: 700;
+}
+.nav-item a:link,
+.nav-item a:visited {
+  padding: .5rem 1rem;
+  margin: 0 .5rem;
+  border-radius: .5rem;
+  color: white;
+  text-decoration: none;
+}
+.nav-item a:hover {
+  cursor: pointer;
+  background-color: rgba(255, 255, 255, .2);
+}
+.nav-item a.is-active-route {
+  border-top-left-radius: 0;
+  border-top-right-radius: 0;
+  border-top: solid 4px rgba(255, 255, 255, .3);
+}
+
+form {
+  max-width: 60rem;
+  margin: auto;
+}
+.action-cell .material-icons {
+  font-size: 1.1rem ;
+}
+.material-icons {
+  vertical-align: bottom;
+}
+#toastHost {
+  position: sticky;
+  bottom: 0;
+}
+.request-text {
+  white-space: pre-line
+}
+
+footer {
+  border-top: solid 1px lightgray;
+  margin: 1rem -1rem 0;
+  padding: 0 1rem;
+}
+footer p {
+  margin: 0;
+}