WIP on uploads (#2)

- Add data types and fields
- Implement in both RethinkDB and SQLite
- Add uploads to backup/restore
- Add empty upload folder to project
- Add indexes to SQLite tables (#15)

src/MyWebLog.Data/SQLite/SQLiteUploadData.fs

@@ -0,0 +1,69 @@
+namespace MyWebLog.Data.SQLite
+
+open System.IO
+open Microsoft.Data.Sqlite
+open MyWebLog
+open MyWebLog.Data
+
+/// SQLite myWebLog web log data implementation        
+type SQLiteUploadData (conn : SqliteConnection) =
+
+    /// Add parameters for uploaded file INSERT and UPDATE statements
+    let addUploadParameters (cmd : SqliteCommand) (upload : Upload) =
+        [ cmd.Parameters.AddWithValue ("@id", UploadId.toString upload.id)
+          cmd.Parameters.AddWithValue ("@webLogId", WebLogId.toString upload.webLogId)
+          cmd.Parameters.AddWithValue ("@path", Permalink.toString upload.path)
+          cmd.Parameters.AddWithValue ("@updatedOn", upload.updatedOn)
+          cmd.Parameters.AddWithValue ("@dataLength", upload.data.Length)
+        ] |> ignore
+    
+    /// Save an uploaded file
+    let add upload = backgroundTask {
+        use cmd = conn.CreateCommand ()
+        cmd.CommandText <- """
+            INSERT INTO upload (
+                id, web_log_id, path, updated_on, data
+            ) VALUES (
+                @id, @webLogId, @path, @updatedOn, ZEROBLOB(@dataLength)
+            )"""
+        addUploadParameters cmd upload
+        do! write cmd
+        
+        cmd.CommandText <- "SELECT ROWID FROM upload WHERE id = @id"
+        let! rowId = cmd.ExecuteScalarAsync ()
+        
+        use dataStream = new MemoryStream (upload.data)
+        use blobStream = new SqliteBlob (conn, "upload", "data", rowId :?> int64)
+        do! dataStream.CopyToAsync blobStream
+    }
+    
+    /// Find an uploaded file by its path for the given web log
+    let findByPath (path : string) webLogId = backgroundTask {
+        use cmd = conn.CreateCommand ()
+        cmd.CommandText <- "SELECT *, ROWID FROM upload WHERE web_log_id = @webLogId AND path = @path"
+        addWebLogId cmd webLogId
+        cmd.Parameters.AddWithValue ("@path", path) |> ignore
+        let! rdr = cmd.ExecuteReaderAsync ()
+        return if rdr.Read () then Some (Map.toUpload rdr) else None
+    }
+    
+    /// Find all uploaded files for the given web log
+    let findByWebLog webLogId = backgroundTask {
+        use cmd = conn.CreateCommand ()
+        cmd.CommandText <- "SELECT *, ROWID FROM upload WHERE web_log_id = @webLogId"
+        addWebLogId cmd webLogId
+        let! rdr = cmd.ExecuteReaderAsync ()
+        return toList Map.toUpload rdr
+    }
+    
+    /// Restore uploads from a backup
+    let restore uploads = backgroundTask {
+        for upload in uploads do do! add upload
+    }
+    
+    interface IUploadData with
+        member _.add upload = add upload
+        member _.findByPath path webLogId = findByPath path webLogId
+        member _.findByWebLog webLogId = findByWebLog webLogId
+        member _.restore uploads = restore uploads
+